IPB

Welcome Guest ( Log In | Register )

 
Reply to this topicStart new topic
EAC and AAC, Does anyone know if a page was ever written for configuring both?
HotshotGG
post Jul 30 2008, 00:22
Post #1





Group: Members
Posts: 1593
Joined: 24-March 02
From: Revere, MA
Member No.: 1607



Can it be done? I am quite baffled. I just noticed that EAC and AAC page was never written. I would write one except I am unsure how exactly you configure EAC and use it as an external compressor with something like Nero AAC. Considering I have had poor luck with the Nero AAC encoder in the past (albeit why I don't encode with it) I was wondering if anyone could lend a helping hand or any assistance in this department. It would be great guide for all of the IPod and Itunes users out there (that doesn't include me). Well anyway if you have any working knowledge at all about this topic please feel free to discuss it here. Thanks. Take care.

This post has been edited by HotshotGG: Jul 30 2008, 00:24


--------------------
College student/IT Assistant
Go to the top of the page
+Quote Post
JasonQ
post Jul 30 2008, 00:39
Post #2





Group: Members
Posts: 43
Joined: 12-October 07
Member No.: 47794



Great question. I would love an answer as well.
Go to the top of the page
+Quote Post
greynol
post Jul 30 2008, 00:48
Post #3





Group: Super Moderator
Posts: 10000
Joined: 1-April 04
From: San Francisco
Member No.: 13167



I see no reason why not, but in the meantime we do have this:
http://www.hydrogenaudio.org/forums/index....showtopic=44310

In general I think stickies suck, but in this one is from someone who truly knows his shit.

If someone does make an EAC AAC article (Synthetic Soul, exec?), please use the others as a boiler plate. Someone made a bit of a mess out of the flac page, but it got fixed. wink.gif


--------------------
Placebophiles: put up or shut up!
Go to the top of the page
+Quote Post
HotshotGG
post Jul 30 2008, 02:16
Post #4





Group: Members
Posts: 1593
Joined: 24-March 02
From: Revere, MA
Member No.: 1607



QUOTE
If someone does make an EAC AAC article (Synthetic Soul, exec?), please use the others as a boiler plate. Someone made a bit of a mess out of the flac page, but it got fixed.


Yeah it didn't make any sense someone thought we should merge both articles together into one, but due to the fact there are so many EAC Guides we don't want the same information to be written over and over again.

QUOTE
If someone does make an EAC AAC article (Synthetic Soul, exec?), please use the others as a boiler plate. Someone made a bit of a mess out of the flac page, but it got fixed.


I noticed that sticky page when I was looking to encode with Nero AAC (The standard input always yells at me though when I try to pipe the file in! it even complains with the Nero AAC Frontend! (Speaking of which I should probably link to that. I am sure somebody will have more luck then I do. There is Frontend that exists so that you can pipe your FLAC files directly to AAC). I am acustomed to using Vorbis, which is a quick skip, hop, and a jump.

Note: I will get the page started and then somebody else can finish it up!

Check this out! I found a guide for configuring CDex with AAC. I will have to incoporate some of this information into the wiki as well.

http://www.fucema.net/2008/3/18/cdex-confi...-nero-aac-codec

This post has been edited by HotshotGG: Jul 30 2008, 02:46


--------------------
College student/IT Assistant
Go to the top of the page
+Quote Post
greynol
post Jul 30 2008, 03:03
Post #5





Group: Super Moderator
Posts: 10000
Joined: 1-April 04
From: San Francisco
Member No.: 13167



Speaking of piping, I made this drag-and-drop batch converter for NeroAacEnc per a request which accepts a variety of lossless formats, preserves basic tag information, and scales the input according to RG album gain. Maybe someone will find it helpful...
CODE
@ECHO OFF

IF "%~1" == "" neroaacenc -help && GOTO end

SET PARAMS=-q0.45

:encode
TITLE Encoding "%~nx1"
IF EXIST "%~1.tag" GOTO encode_shift
IF EXIST "%~dpn1.m4a" GOTO encode_shift
SET /p nul=Encoding "%~nx1" <nul
IF /i "%~x1" == ".wav" (CALL :encode_wav %1
) ELSE (IF /i "%~x1" == ".wv" (CALL :encode_wv %1
) ELSE (IF /i "%~x1" == ".tak" (CALL :encode_tak %1
) ELSE (IF /i "%~x1" == ".flac" (CALL :encode_flac %1
) ELSE (IF /i "%~x1" == ".ape" (CALL :encode_ape %1
) ELSE ECHO ... Invalid file && GOTO encode_shift
)
)
)
)
ECHO Done
:encode_shift
SHIFT
IF "%~1" EQU "" ECHO. && GOTO end
GOTO encode

:encode_wav
SET /p nul=... <nul
neroaacenc %PARAMS% -if %1 -of "%~dpn1.m4a" 2>nul
GOTO :eof

:encode_wv
CALL :taginfo %1
SET /p nul=... <nul
wvunpack -q %1 - | %SCALE% neroaacenc %PARAMS% -if - -of "%~dpn1.m4a" 2>nul
neroAacTag "%~dpn1.m4a" %TAGINFO% 2>nul
GOTO :eof

:encode_tak
CALL :taginfo %1
SET /p nul=... <nul
takc -d %1 - | %SCALE% neroaacenc %PARAMS% -if - -of "%~dpn1.m4a" 2>nul
neroAacTag "%~dpn1.m4a" %TAGINFO% 2>nul
GOTO :eof

:encode_flac
CALL :taginfo %1
SET /p nul=... <nul
flac -dcs %1 | %SCALE% neroAacEnc %PARAMS% -if - -of "%~dpn1.m4a" 2>nul
neroAacTag "%~dpn1.m4a" %TAGINFO% 2>nul
GOTO :eof

:encode_ape
CALL :taginfo %1
SET /p nul=... <nul
mac %1 - -d 2>nul | %SCALE% neroaacenc %PARAMS% -if - -of "%~dpn1.m4a" 2>nul
neroAacTag "%~dpn1.m4a" %TAGINFO% 2>nul
GOTO :eof

:taginfo
tag %1 2> "%~1.tag"
SET SCALE=
FOR /F "usebackq tokens=1*" %%X IN (`findstr "Title:" "%~1.tag"`) DO (
SET title=%%Y
)
FOR /F "usebackq tokens=1*" %%X IN (`findstr "Artist:" "%~1.tag"`) DO (
SET artist=%%Y
)
FOR /F "usebackq tokens=1*" %%X IN (`findstr "Album:" "%~1.tag"`) DO (
SET album=%%Y
)
FOR /F "usebackq tokens=1*" %%X IN (`findstr "Year:" "%~1.tag"`) DO (
SET year=%%Y
)
FOR /F "usebackq tokens=1*" %%X IN (`findstr "Track:" "%~1.tag"`) DO (
SET track=%%Y
)
FOR /F "usebackq tokens=1*" %%X IN (`findstr "Genre:" "%~1.tag"`) DO (
SET genre=%%Y
)
FOR /F "usebackq tokens=1*" %%X IN (`findstr "Comment:" "%~1.tag"`) DO (
SET comment=%%Y
)
SET TAGINFO=-meta:title="%title%" -meta:artist="%artist%" -meta:album="%album%" -meta:year="%year%" -meta:track="%track%" -meta:genre="%genre%" -meta:comment="%comment%"
FOR /F "usebackq tokens=1,2* delims== " %%X IN (`findstr "replaygain_album_gain" "%~1.tag"`) DO (
SET SCALE=%%Y
)
IF DEFINED SCALE FOR /F %%X IN ('EVAL 10^^^^^(%SCALE%/20^)') DO SET SCALE=sox -v %%X -t wav - -t wav - 2^>nul ^|
DEL "%~1.tag"
GOTO :eof

:end
PAUSE

Tag.exe can be found at Synthetic Soul's website. Eval.exe can be found here. Sox.exe can be found at sourceforge.net. A special build of mac.exe that provides for stdout can be found at rarewares.org or you can get an updated one at etree.org.

EDIT: Spelling and grammar. The code is still the same.

This post has been edited by greynol: Jul 30 2008, 05:42


--------------------
Placebophiles: put up or shut up!
Go to the top of the page
+Quote Post
DARcode
post Jul 30 2008, 07:08
Post #6





Group: Members (Donating)
Posts: 681
Joined: 10-January 05
From: Italy
Member No.: 18968



QUOTE (greynol @ Jul 30 2008, 04:03) *
Speaking of piping, I made this drag-and-drop batch converter for NeroAacEnc per a request which accepts a variety of lossless formats, preserves basic tag information, and scales the input according to RG album gain. Maybe someone will find it helpful...
I do biggrin.gif , thanks a bunch!


--------------------
WavPack 4.70.0 -b384hx6cmv/qaac 2.41 -V 100
Go to the top of the page
+Quote Post

Reply to this topicStart new topic
1 User(s) are reading this topic (1 Guests and 0 Anonymous Users)
0 Members:

 



RSS Lo-Fi Version Time is now: 31st July 2014 - 14:42