IPB

Welcome Guest ( Log In | Register )

REACT 2 Released, New version of this popular ripping tool
Synthetic Soul
post Nov 17 2006, 08:53
Post #1





Group: Super Moderator
Posts: 4887
Joined: 12-August 04
From: Exeter, UK
Member No.: 16217



REACT 2.0 is not backward compatible with version 1.0. This version is more powerful, easier to use and configure. It uses only two configuration scripts: REACT-image.cfg, and REACT-track.cfg. Image mode (F10) is recommended, as it may be used for creating both an image and tracks, and is a little more robust. With Nyaochi's excellent ACDIR, it will split the image to tracks while encoding. You can pick and choose from which formats you want by only editing a few characters in the .cfg file. See examples below.

NEWS
  • Only one configuration file for each mode (image/track).
  • Simpler user-configuration, located in first section of .cfg file (Alt-F3).
  • Built-in support for CoverDownloader (albumart.exe). Runs when hitting F10/F4. Alt-F10 for CoverDownloader only.
  • Adds cover pictures to FLAC (with 1.1.3beta) and MP3 by using my new tool, metamp3.exe
  • Optionally scans and tags ReplayGain for all formats. May also apply album gain on MP3/AAC files.
  • Writes ID3v2.3 ReplayGain tags on MP3's (Winamp/Foobar compatible), via metamp3.exe
  • Should fix random REACT exiting, reported by some users.
  • User may now minimize EAC while ripping (EAC will auto-restore when ripping done, and save log).
  • Accepts both "Various" and "Various Artists" as compilation disk.
  • If CreateAllCuesheets=1 is set in INI file, and EAC is set up to extract to a fixed directory, REACT will save all types of cuesheets when hitting F4/F10. Cuesheets can be accessed from scripts by @albumfile@ variable. E.g. "@albumfile@.[mg].cue"
  • The (unsafe) @islast@ variable for track mode is not supported anymore. Use @track@==@numtracks@ test instead, or image mode.
FEATURES
The wiki has more info : http://wiki.hydrogenaudio.org/index.php?title=REACT

More information and download in the thread REACT 2, EAC plugin


--------------------
I'm on a horse.
Go to the top of the page
+Quote Post
 
Start new topic
Replies
tycho
post Nov 20 2006, 19:48
Post #2





Group: Members
Posts: 345
Joined: 5-August 03
Member No.: 8183



The coverdownloader will fill in a name <destdir>\<album>.jpg. You should not change this name! Simply save it to the suggested directory/file name (Doubleclick on the cover you want). The .cfg script will then take care of copying it to the folder where the encoded audio will be stored, and change name to e.g. folder.jpg.

The destination directory you set up in EAC is only a temporary directory - the files are copied/moved to the final destinations by the script.

If you don't find all covers you expect, rename some of the files in the coverdownloader\scripts directory from "<name>.boo.disabled" to "<name>.boo". Try google.boo and discogs.boo. itunes.boo does unfortunately not work anylonger.

There is already a hotkey for only launching coverdownloader (mentioned in Readme): Alt-F10

This post has been edited by tycho: Nov 20 2006, 19:56
Go to the top of the page
+Quote Post
wolfsong
post Nov 21 2006, 14:02
Post #3





Group: Members
Posts: 342
Joined: 18-September 05
From: UC, TX
Member No.: 24536



QUOTE (tycho @ Nov 20 2006, 12:48) *
The destination directory you set up in EAC is only a temporary directory - the files are copied/moved to the final destinations by the script.

I tested this again this morning and this step isn't happening. The cover and log file are still in the EAC directory when using track config and deleted when using image config.

Track Config:
CODE
@echo off
chcp 1252
title @track@/@numtracks@ - "@album@"

rem ** You may consider using image mode (F10)
rem ** as it supports creating tracks via acdir.exe,
rem ** and post-processing will always work (see below).


REM ================== USER SETTINGS ======================


REM ---- Enable/disable track formats:

rem ** Flac requires flac.exe/metaflac.exe (v1.1.3)
rem ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
rem ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.

set Flac=0
set Wavpack=0
set LameMP3=1
set NeroAac=0
set OggEnc2=0

REM ---- General settings:

set Debug=0

rem ** I prefer applying album gain 92dB to get a reasonable
rem ** volume for my DAP. The RG tags are still relative
rem ** to 89dB SPL, i.e. album gain will be about -3.0dB.

set ReplayGain=1
set ApplyMp3AacAlbumGain=1
set AdjustMp3AacAlbumGain_dB=+0.0

REM ---- Encoder options:

set Flac_opt=-5 -f
set Wavpack_opt=-hmy
set LameMP3_opt=-V4 --vbr-new --noreplaygain --nohist
rem ** Nero LC-AAC @ ~ 90kbps - great for e.g. iPods:
set NeroAac_opt=-lc -q 0.22
set OggEnc2_opt=-q 3.0

set Flac_ver=1.1.3b2
set LameMP3_ver=3.97
set NeroAac_ver=1.0.0.2

REM ---- Output directories and track names:

set OutRoot=E:\TAGZ

rem ** Track dirs:
set Flac_TrackDir=%OutRoot%\Flac\$cdartist$\[$year$] $album$
set Wavpack_TrackDir=%OutRoot%\Wavpack\$cdartist$\[$year$] $album$
set MP3_TrackDir=%OutRoot%\$cdartist$\$album$
IF @various@==1 set MP3_TrackDir=%OutRoot%\Various Artists\$album$
set AAC_TrackDir=%OutRoot%\AAC\$cdartist$\[$year$] $album$
set OGG_TrackDir=%OutRoot%\OGG\$cdartist$\[$year$] $album$

rem ** Track names:
if @various@==0 set TrackName=[$track$] $title$
if @various@==1 set TrackName=[$track$] $title$ ($artist$)


REM ============== BEGIN MAIN SCRIPT ==================


if %Debug%==1 echo on


REM ---- Track ----


if %Flac%==0 goto end_flac_tracks
set dest=%Flac_TrackDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\flac.exe %Flac_opt% -T artist="@artist@" -T album="@album@" -T tracknumber="@track@/@numtracks@" -T title="@title@" -T date="@year@" -T genre="@genre@" -T comment="Ripped with EAC/REACT" "@source@" -o "%dest%\%TrackName%.flac"
:end_flac_tracks


if %Wavpack%==0 goto end_wavpack_tracks
set dest=%Wavpack_TrackDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\wavpack.exe %Wavpack_opt% -w artist="@artist@" -w album="@album@" -w track="@track@/@numtracks@" -w title="@title@" -w year="@year@" -w genre="@genre@" -w comment="Ripped with EAC/REACT" "@source@" "%dest%\%TrackName%.wv"
title @track@/@numtracks@ - "@album@"
:end_wavpack_tracks


if %LameMP3%==0 goto end_mp3_tracks
set dest=%MP3_TrackDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\lame.exe %LameMP3_opt% "@source@" "%dest%\%TrackName%.mp3"
@tools@\metamp3.exe --artist "@artist@" --album "@album@" --track @track@/@numtracks@ --title "@title@" --year "@year@" --genre "@genre@" --comment "Ripped with EAC/REACT" --frame TPE2:"@cdartist@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME %LameMP3_ver% %LameMP3_opt%" "%dest%\%TrackName%.mp3"
:end_mp3_tracks


if %NeroAac%==0 goto end_aac_tracks
set dest=%AAC_TrackDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\neroAacEnc.exe %NeroAac_opt% -if "@source@" -of "%dest%\%TrackName%.m4a"
@tools@\neroAacTag.exe "%dest%\%TrackName%.m4a" -meta:artist="@artist@" -meta:album="@album@" -meta:track=@track@ -meta:totaltracks=@numtracks@ -meta:title="@title@" -meta:year="@year@" -meta:genre="@genre@" -meta:comment="Ripped with EAC/REACT"
:end_aac_tracks


if %OggEnc2%==0 goto end_ogg_tracks
set dest=%OGG_TrackDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\oggenc2.exe %OggEnc2_opt% -c artist="@artist@" -c album="@album@" -c tracknumber="@track@/@numtracks@" -c title="@title@" -c date="@year@" -c genre="@genre@" -c comment="Ripped with EAC/REACT" "@source@" -o "%dest%\%TrackName%.ogg"
:end_ogg_tracks


rem ** Delete the source .wav

del "@source@"


REM ---- Post-processing ----


rem ** Scan and compute ReplayGain and add cover picture for supported formats.
rem **
rem ** NB: The following will only work if at least the last track is selected,
rem ** and it is a regular audio track.

if not @track@==@numtracks@ goto end_post_process

set add_rg=%ReplayGain%
set add_meta=%add_rg%
set add_cover=0
set small_cover=@cover@

if %ReplayGain%==1 (
set MetaFlac_RG=--add-replay-gain
set MetaMp3_RG=--replay-gain
)
if %ApplyMp3AacAlbumGain%==1 (
set AacGain_RG=/a /o /c /d %AdjustMp3AacAlbumGain_dB%
set MetaMP3_RG=--apply-gain album%AdjustMp3AacAlbumGain_dB%
set add_rg=1
set add_meta=1
)
if exist "@cover@" (
set MetaFlac_cover=--import-picture="|image/jpeg|||@cover@"
set MetaMP3_cover=--pict "{3}@cover@"
set AacTag_cover=-add-cover:front:"@cover@"
set add_cover=1
set add_meta=1
)


rem ** Formats:

if %Flac%==1 (
pushd "%Flac_TrackDir%"
if %add_meta%==1 @tools@\Glob.exe -v -c @tools@\metaflac.exe %MetaFlac_RG% %MetaFlac_cover% *.flac
if exist "@eaclog@" copy "@eaclog@" "EAClog.txt"
if %add_cover%==1 copy "@cover@" "folder.jpg"
popd
)

if %Wavpack%==1 (
pushd "%Wavpack_TrackDir%"
if %ReplayGain%==1 @tools@\wvgain.exe -a *.wv
if exist "@eaclog@" copy "@eaclog@" "EAClog.txt"
if %add_cover%==1 copy "@cover@" "folder.jpg"
popd
)

if %LameMP3%==1 (
pushd "%MP3_TrackDir%"
if %add_meta%==1 @tools@\metamp3.exe %MetaMP3_RG% %MetaMP3_cover% *.mp3
popd
)

if %NeroAac%==1 (
pushd "%AAC_TrackDir%"
if %add_cover%==1 for %%i in (*.m4a) do @tools@\neroAacTag.exe "%%i" %AacTag_cover%
if %add_rg%==1 @tools@\aacgain.exe %AacGain_RG% *.m4a > "gainlog.txt"
popd
)

if %OggEnc2%==1 (
pushd "%OGG_TrackDir%"
if %ReplayGain%==1 @tools@\vorbisgain.exe -a *.ogg
popd
)


rem ** Cleanup

del "@eaclog@"
del "@albumfile@.[*].cue"
del "@cover@"
:end_post_process


REM ================ END MAIN SCRIPT ===================


if %Debug%==1 (
pause
REM exit
)

rem ** Delete this .bat file:
del %0

Image Config:
CODE
@echo off
chcp 1252
title REACT - "@album@"


REM ================== USER SETTINGS ======================


rem ** To archive a CD as one large "image", you must set
rem ** ImageExt=... in the REACT.ini file (Press Alt-F2).
rem ** This will set the @imageext@ variable. Extensions
rem ** currently supported: flac, wv, mp3. Set to 'wav'
rem ** for no image archiving (default).

REM ---- Enable/disable additional track formats:

rem ** Splits the wav-image into tracks during encoding, using ACDIR.
rem ** Flac requires flac.exe/metaflac.exe (v1.1.3)
rem ** NeroAac requires NeroAacEnc.exe/NeroAacTag.exe/AacGain.exe.
rem ** OggEnc2 requires OggEnc2.exe/VorbisGain.exe.

set Flac=0
set Wavpack=0
set LameMP3=1
set NeroAac=0
set OggEnc2=0

REM ---- General settings ----

set Debug=0

rem ** I prefer applying album gain 92dB to get a reasonable
rem ** volume for my DAP. The RG tags are still relative
rem ** to 89dB SPL, i.e. album gain will be about -3.0dB.

set ReplayGain=1
set ApplyMp3AacAlbumGain=1
set AdjustMp3AacAlbumGain_dB=+0.0

REM ---- Encoder options ----

set Flac_opt=-5 -f
set Wavpack_opt=-hmy
set LameMP3_opt=-V4 --vbr-new --noreplaygain --nohist
rem ** Nero LC-AAC @ ~ 90kbps - great for e.g. iPods:
set NeroAac_opt=-lc -q 0.22
set OggEnc2_opt=-q 3.0

set Flac_ver=1.1.3b2
set LameMP3_ver=3.97
set NeroAac_ver=1.0.0.2

REM ---- Output directories and track names ----

set OutRoot=E:\TAGZ

rem ** Image dirs:
set Flac_ImageDir=%OutRoot%\Flac-Images\$cdartist$
set Wavpack_ImageDir=%OutRoot%\Wavpack-Images\$cdartist$
set MP3_ImageDir=%OutRoot%\MP3-Images\$cdartist$

rem ** Track dirs:
set Flac_TrackDir=%OutRoot%\Flac\$cdartist$\[$year$] $album$
set Wavpack_TrackDir=%OutRoot%\Wavpack\$cdartist$\[$year$] $album$
set MP3_TrackDir=%OutRoot%\$cdartist$\$album$
IF @various@==1 set MP3_TrackDir=%OutRoot%\Various Artists\$album$
set AAC_TrackDir=%OutRoot%\AAC\$cdartist$\[$year$] $album$
set OGG_TrackDir=%OutRoot%\OGG\$cdartist$\[$year$] $album$

rem ** Track names (for ACDIR):
if @various@==0 set TrackName=[$n] $~t
if @various@==1 set TrackName=[$n] $~t ($~a)


REM ============== BEGIN MAIN SCRIPT ==================


if %Debug%==1 echo on

set add_rg=%ReplayGain%
set add_meta=%add_rg%
set add_cover=0
set small_cover=@cover@

if %ReplayGain%==1 (
set Flac_RG=--replay-gain
set MetaFlac_RG=--add-replay-gain
set MetaMp3_RG=--replay-gain
)
if %ApplyMp3AacAlbumGain%==1 (
set AacGain_RG=/a /o /c /d %AdjustMp3AacAlbumGain_dB%
set MetaMP3_RG=--apply-gain album%AdjustMp3AacAlbumGain_dB%
set add_rg=1
set add_meta=1
)
if exist "@cover@" (
set Flac_cover=--picture="|image/jpeg|||@cover@"
set MetaFlac_cover=--import-picture="|image/jpeg|||@cover@"
set MetaMP3_cover=--pict "{3}@cover@"
set AacTag_cover_acdir=-add-cover:front:$q@cover@$q
set add_cover=1
set add_meta=1
)


REM ---- Image ----


if not "@imageext@"=="flac" goto end_flac_image
set dest=%Flac_ImageDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\flac.exe %Flac_opt% %Flac_RG% %Flac_RG% %Flac_cover% -T artist="@artist@" -T album="@album@" -T totaltracks="@numtracks@" -T date="@year@" -T genre="@genre@" -T comment="Ripped with EAC/REACT" -T cuesheet="@@cuesheet@" -T eaclog="@@eaclog@" "@source@" -o "@image@"
move "@image@" "%dest%"
copy "@cuesheet@" "%dest%"
if %add_cover%==1 copy "@cover@" "%dest%\@basename@.jpg"
:end_flac_image


if not "@imageext@"=="wv" goto end_wavpack_image
set dest=%Wavpack_ImageDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\wavpack.exe %Wavpack_opt% -w artist="@artist@" -w album="@album@" -w totaltracks="@numtracks@" -w year="@year@" -w genre="@genre@" -w comment="Ripped with EAC/REACT" -w cuesheet="@@cuesheet@" -w eaclog="@@eaclog@" "@source@" "@image@"
title REACT - "@album@"
move "@image@" "%dest%"
copy "@cuesheet@" "%dest%"
if %add_cover%==1 copy "@cover@" "%dest%\@basename@.jpg"
:end_wavpack_image

if not "@imageext@"=="mp3" goto end_mp3_image
set dest=%MP3_ImageDir%
if not exist "%dest%" mkdir "%dest%"
@tools@\lame.exe %LameMP3_opt% "@source@" "@image@"
@tools@\metamp3.exe %MetaMP3_RG% %MetaMP3_cover% --artist "@artist@" --album "@album@" --track @numtracks@ --year "@year@" --genre "@genre@" --comment "Ripped with EAC/REACT" --frame TPE2:"@cdartist@" --frame TENC:"%USERNAME%" --frame TSSE:"LAME %LameMP3_ver% %LameMP3_opt%" "@image@"
move "@image@" "%dest%"
copy "@cuesheet@" "%dest%"
if %add_cover%==1 copy "@cover@" "%dest%\@basename@.jpg"
:end_mp3_image



REM ---- Tracks ----


if %Flac%==0 goto end_flac_tracks
set dest=%Flac_TrackDir%
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.flac" --pipe "title $n/$N flac $#T & @tools@\flac.exe %Flac_opt% -T artist=$#a -T album=$#T -T title=$#t -T tracknumber=$n/$N -T date=$q@year@$q -T genre=$q@genre@$q -T comment=$qRipped with EAC/REACT$q - -o $#o" "@sourcecuesheet@"
if %add_meta%==1 (
pushd "%dest%"
@tools@\Glob.exe -v -c @tools@\metaflac.exe %MetaFlac_RG% %MetaFlac_cover% *.flac
popd
)
copy "@eaclog@" "%dest%\EAClog.txt"
if %add_cover%==1 copy "@cover@" "%dest%\folder.jpg"
if exist "@albumfile@.[*].cue" copy "@albumfile@.[*].cue" "%dest%"
:end_flac_tracks


if %Wavpack%==0 goto end_wavpack_tracks
set dest=%Wavpack_TrackDir%
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.wv" --pipe "@tools@\wavpack.exe %Wavpack_opt% -w artist=$#a -w album=$#T -w title=$#t -w track=$n/$N -w year=$q@year@$q -w genre=$q@genre@$q -w comment=$qRipped with EAC/REACT$q - $#o" "@sourcecuesheet@"
if %ReplayGain%==1 (
pushd "%dest%"
@tools@\wvgain.exe -a *.wv
popd
)
title REACT - "@album@"
copy "@eaclog@" "%dest%\EAClog.txt"
if %add_cover%==1 copy "@cover@" "%dest%\folder.jpg"
if exist "@albumfile@.[*].cue" copy "@albumfile@.[*].cue" "%dest%"
:end_wavpack_tracks


if %LameMP3%==0 goto end_mp3_tracks
set dest=%MP3_TrackDir%
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.mp3" --pipe "title $n/$N mp3 $#T & @tools@\lame.exe %LameMP3_opt% - $#o & @tools@\metamp3.exe --artist $#a --album $#T --title $#t --track $n/$N --year $q@year@$q --genre $q@genre@$q --comment $qRipped with EAC/REACT$q --frame TPE2:$q@cdartist@$q --frame TENC:$q%USERNAME%$q --frame TSSE:$qLAME %LameMP3_ver% %LameMP3_opt%$q $#o" "@sourcecuesheet@"
if %add_meta%==1 (
pushd "%dest%"
@tools@\metamp3.exe %MetaMP3_RG% %MetaMP3_cover% *.mp3
popd
)
REM copy "@eaclog@" "%dest%\EAClog.txt"
REM if %add_cover%==1 copy "@cover@" "%dest%\folder.jpg"
:end_mp3_tracks


if %NeroAac%==0 goto end_aac_tracks
set dest=%AAC_TrackDir%
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.m4a" --pipe "title $n/$N aac $#T & @tools@\neroAacEnc.exe %NeroAac_opt% -if - -of $#o & @tools@\neroAacTag.exe $#o %AacTag_cover_acdir% -meta:artist=$#a -meta:album=$#T -meta:title=$#t -meta:track=$n -meta:totaltracks=$N -meta:year=$q@year@$q -meta:genre=$q@genre@$q -meta:comment=$qRipped with EAC/REACT$q" "@sourcecuesheet@"
if %add_rg%==1 (
pushd "%dest%"
@tools@\aacgain.exe %AacGain_RG% *.m4a > gainlog.txt
popd
)
REM copy "@eaclog@" "%dest%\EAClog.txt"
REM if %add_cover%==1 copy "@cover@" "%dest%\folder.jpg"
:end_aac_tracks


if %OggEnc2%==0 goto end_ogg_tracks
set dest=%OGG_TrackDir%
@tools@\acdir.exe --overwrite --output "%dest%\%TrackName%.ogg" --pipe "title $n/$N ogg $#T & @tools@\oggenc2.exe %OggEnc2_opt% -c artist=$#a -c album=$#T -c title=$#t -c tracknumber=$n/$N -c date=$q@year@$q -c genre=$q@genre@$q -c comment=$qRipped with EAC/REACT$q - -o $#o" "@sourcecuesheet@"
if %ReplayGain%==1 (
pushd "%dest%"
@tools@\vorbisgain.exe -a *.ogg
popd
)
REM copy "@eaclog@" "%dest%\EAClog.txt"
REM if %add_cover%==1 copy "@cover@" "%dest%\folder.jpg"
:end_ogg_tracks


REM ================ END MAIN SCRIPT ===================

if %Debug%==1 (
pause
REM exit
)

rem ** Cleanup

del "@source@"
del "@eaclog@"
del "@cuesheet@"
del "@albumfile@.[*].cue"
del "@cover@"

rem ** Delete this .bat file:
del %0


Also, are boolean arguements supported? So something like:
CODE
IF @various@==1 set MP3_TrackDir=%OutRoot%\Various Artists\Collections\$album$
IF @various@==1 AND IF @genre@==Soundtrack set MP3_TrackDir=%OutRoot%\Various Artists\Soundtracks\$album$


This post has been edited by wolfsong: Nov 21 2006, 14:13


--------------------
[url="http://www.last.fm/user/wolfsong/"]Last.fm Profile[/url]
Go to the top of the page
+Quote Post
Synthetic Soul
post Nov 21 2006, 14:24
Post #4





Group: Super Moderator
Posts: 4887
Joined: 12-August 04
From: Exeter, UK
Member No.: 16217



QUOTE (wolfsong @ Nov 21 2006, 13:02) *
Also, are boolean arguements supported? So something like:
CODE
IF @various@==1 set MP3_TrackDir=%OutRoot%\Various Artists\Collections\$album$
IF @various@==1 AND IF @genre@==Soundtrack set MP3_TrackDir=%OutRoot%\Various Artists\Soundtracks\$album$
You can do:

CODE
IF @various@==1 IF @genre@==Soundtrack set MP3_TrackDir=%OutRoot%\Various Artists\Soundtracks\$album$

The second IF will only run if the first is true.

If you needed to get more complex you can start using brackets and/or ELSE, e.g.:

CODE
IF @various@==1 (
  IF @genre@==Soundtrack (
    REM CD is both VA and a soundtrack
    SET MP3_TrackDir=%OutRoot%\Various Artists\Soundtracks\$album$
  ) ELSE (
    REM CD is VA but not a soundtrack
    SET MP3_TrackDir=%OutRoot%\Various Artists\$album$
  )
) ELSE (
  REM CD is not VA
  SET MP3_TrackDir=%OutRoot%\$artist$\$album$
)


This post has been edited by Synthetic Soul: Nov 21 2006, 14:32


--------------------
I'm on a horse.
Go to the top of the page
+Quote Post
wolfsong
post Nov 21 2006, 14:48
Post #5





Group: Members
Posts: 342
Joined: 18-September 05
From: UC, TX
Member No.: 24536



QUOTE (Synthetic Soul @ Nov 21 2006, 07:24) *
You can do:

Nifty. I like the more complex option simply because it's more readable.

I also notice that albumart tends to hang and take up CPU resources (around 95%) for 30 to 90 seconds while trying to save the image. I know this isn't tycho's code, just wondering if anyone else is seeing this too.

@tycho: could this extra bit of code i'm using be throwing off how the cover image is being handled?

This post has been edited by wolfsong: Nov 21 2006, 14:50


--------------------
[url="http://www.last.fm/user/wolfsong/"]Last.fm Profile[/url]
Go to the top of the page
+Quote Post
tycho
post Nov 21 2006, 16:02
Post #6





Group: Members
Posts: 345
Joined: 5-August 03
Member No.: 8183



QUOTE (wolfsong @ Nov 21 2006, 05:48) *
QUOTE (Synthetic Soul @ Nov 21 2006, 07:24) *

You can do:

Nifty. I like the more complex option simply because it's more readable.

I also notice that albumart tends to hang and take up CPU resources (around 95%) for 30 to 90 seconds while trying to save the image. I know this isn't tycho's code, just wondering if anyone else is seeing this too.

@tycho: could this extra bit of code i'm using be throwing off how the cover image is being handled?

First, although it looks more readable with the paranthesis blocks in the script, e.g.
IF @various@==1 (
set MP3_TrackDir=%OutRoot%\Various Artists\$album$
echo %MP3_TrackDir%
)
it will fail if either %OutRoot% or $album$ contains a ')' character, because the silly dos-script interprets it as closing of the block!
Also be aware of that the echo line will not print out the value you set above! First outside the parathesis block it will be readable!
Conclusion: use labels and 'goto's instead to avoid both of these problems.

Secondly, the discogs.boo script does find many covers, but I think it is because of this that albumart hangs. Disable it.

This post has been edited by tycho: Nov 21 2006, 16:07
Go to the top of the page
+Quote Post
wolfsong
post Nov 21 2006, 21:01
Post #7





Group: Members
Posts: 342
Joined: 18-September 05
From: UC, TX
Member No.: 24536



QUOTE (tycho @ Nov 21 2006, 09:02) *
Conclusion: use labels and 'goto's instead to avoid both of these problems.

Can you give me an idea what this looks like? I'm not sure what language syntax is being used in the scripting? Is it pure DOS syntax? I'm afraid my brain can't access that file any longer (but I may have a book on the shelf at home).
QUOTE (tycho @ Nov 21 2006, 09:02) *
Secondly, the discogs.boo script does find many covers, but I think it is because of this that albumart hangs. Disable it.

Hmm then it may just be that it hasn't finished grabbing covers when I try to save one because I tend to find one right away. I'll hold off on disabling it and giving it a chance to run first but if it gets too annoyin it'a good to know what the problem is. Thanks.


--------------------
[url="http://www.last.fm/user/wolfsong/"]Last.fm Profile[/url]
Go to the top of the page
+Quote Post

Posts in this topic
- Synthetic Soul   REACT 2 Released   Nov 17 2006, 08:53
- - Xenion   i'm new to this tool. is it possible to rip as...   Nov 17 2006, 11:39
- - tycho   If you rip as image, you may encode to either a wa...   Nov 17 2006, 12:26
- - drbeachboy   Hi Tycho, With embedded cuesheets (Especially wit...   Nov 17 2006, 18:12
|- - Synthetic Soul   QUOTE (drbeachboy @ Nov 17 2006, 17:12) H...   Nov 17 2006, 18:34
- - valnar   You know, I never had to uninstall REACT v1.0. Ho...   Nov 17 2006, 21:32
- - Keykey   I am a total newbie to REACT, sorry. How do I get...   Nov 17 2006, 21:39
- - Gow   Awesome release. Keep up the good work.   Nov 17 2006, 23:34
- - wolfsong   Can't wait to try this release tonight when I ...   Nov 18 2006, 00:38
- - HbG   Just set it up to work with flake and metaflac for...   Nov 18 2006, 02:03
- - hanning   It seems that the following section in REACT-image...   Nov 18 2006, 04:56
- - wolfsong   So I just tried it out and like the new config but...   Nov 18 2006, 07:54
- - Synthetic Soul   QUOTE (Keykey @ Nov 17 2006, 20:39) I am ...   Nov 18 2006, 10:49
|- - wolfsong   QUOTE (Synthetic Soul @ Nov 18 2006, 03:4...   Nov 18 2006, 19:09
- - drbeachboy   I also found the tag lines for embedding the cuesh...   Nov 18 2006, 18:32
- - tycho   Thanks for all the great feedback. I have uploaded...   Nov 19 2006, 02:08
|- - wolfsong   QUOTE (tycho @ Nov 18 2006, 19:08) @wolfs...   Nov 19 2006, 05:12
|- - wolfsong   QUOTE (tycho @ Nov 18 2006, 19:08) Thanks...   Nov 25 2006, 07:57
- - tycho   AFAIK, there is no explicit ID stored on the CD, b...   Nov 19 2006, 11:15
|- - wolfsong   QUOTE (tycho @ Nov 19 2006, 04:15) AFAIK,...   Nov 19 2006, 13:42
|- - bhoar   QUOTE (wolfsong @ Nov 19 2006, 08:42) hmm...   Nov 19 2006, 20:40
- - spoon   There is ISRC (International Standards Recoding Co...   Nov 19 2006, 20:47
- - sdgenxr   Thanks for the great release tycho! This vers...   Nov 20 2006, 05:44
|- - tycho   QUOTE (sdgenxr @ Nov 19 2006, 20:44) My q...   Nov 20 2006, 08:52
- - TomGroove   excellent, I like the new version. Struggled a lit...   Nov 20 2006, 16:23
- - wolfsong   I'm having a problem with CoverArtDownloader. ...   Nov 20 2006, 17:41
- - tycho   The coverdownloader will fill in a name <destdi...   Nov 20 2006, 19:48
|- - wolfsong   QUOTE (tycho @ Nov 20 2006, 12:48) The co...   Nov 20 2006, 21:00
|- - wolfsong   QUOTE (tycho @ Nov 20 2006, 12:48) The de...   Nov 21 2006, 14:02
|- - Synthetic Soul   QUOTE (wolfsong @ Nov 21 2006, 13:02) Als...   Nov 21 2006, 14:24
|- - wolfsong   QUOTE (Synthetic Soul @ Nov 21 2006, 07:2...   Nov 21 2006, 14:48
|- - tycho   QUOTE (wolfsong @ Nov 21 2006, 05:48) QUO...   Nov 21 2006, 16:02
|- - wolfsong   QUOTE (tycho @ Nov 21 2006, 09:02) Conclu...   Nov 21 2006, 21:01
- - countryman   Hi, I have downloaded REACT 2 but cannot get it t...   Nov 22 2006, 00:36
- - drbeachboy   Try pressing the "F10" key on your keybo...   Nov 22 2006, 02:36
- - wolfsong   @tycho Even when I leave out this extra bit of cod...   Nov 22 2006, 06:34
|- - tycho   QUOTE (wolfsong @ Nov 21 2006, 21:34) @ty...   Nov 22 2006, 09:39
|- - wolfsong   QUOTE (tycho @ Nov 22 2006, 02:39) QUOTE ...   Nov 22 2006, 12:53
- - tycho   Ah. The cover is embeded in the tracks for flac, m...   Nov 22 2006, 15:22
|- - wolfsong   QUOTE (tycho @ Nov 22 2006, 08:22) Ah. Th...   Nov 22 2006, 16:13
|- - wolfsong   QUOTE (tycho @ Nov 22 2006, 08:22) If you...   Nov 23 2006, 19:26
- - Synthetic Soul   It is basic DOS commands BTW. http://www.ss64.com...   Nov 22 2006, 16:44
- - sdgenxr   Image creation assistance needed. For some reason...   Nov 25 2006, 06:33
|- - wolfsong   QUOTE (sdgenxr @ Nov 24 2006, 23:33) How ...   Nov 25 2006, 06:42
- - Martin H   @tycho 1. Would you please add an option for addi...   Nov 26 2006, 18:10
|- - wolfsong   QUOTE (Martin H @ Nov 26 2006, 11:10) 2. ...   Nov 26 2006, 18:59
- - tycho   Again, Thanks for all feedback. @sdgenxr: You mus...   Nov 26 2006, 22:48
|- - wolfsong   QUOTE (tycho @ Nov 26 2006, 15:48) @wolfs...   Nov 27 2006, 01:08
|- - tycho   QUOTE (wolfsong @ Nov 26 2006, 16:08) QUO...   Nov 27 2006, 09:39
|- - wolfsong   QUOTE (tycho @ Nov 27 2006, 02:39) The li...   Nov 27 2006, 15:07
- - Martin H   @wolfsong Thank's for your reply Btw, the ...   Nov 26 2006, 23:31
- - tycho   Correct.   Nov 27 2006, 15:23
- - mogorp   I have found React 2 to work flawlessly. I just h...   Nov 27 2006, 21:15
|- - wolfsong   QUOTE (mogorp @ Nov 27 2006, 14:15) 2. W...   Nov 27 2006, 21:20
- - tycho   QUOTE 1. Can you explain the default settings for ...   Nov 28 2006, 07:37
- - wolfsong   I keep running into issues and I think it's so...   Nov 28 2006, 15:30
|- - Synthetic Soul   QUOTE (wolfsong @ Nov 28 2006, 14:30) Las...   Nov 28 2006, 16:38
||- - tycho   QUOTE (Synthetic Soul @ Nov 28 2006, 07:3...   Nov 28 2006, 16:47
||- - wolfsong   QUOTE (Synthetic Soul @ Nov 28 2006, 07:3...   Nov 28 2006, 17:52
|||- - Synthetic Soul   QUOTE (wolfsong @ Nov 28 2006, 16:52) I...   Nov 29 2006, 15:26
|||- - wolfsong   QUOTE (Synthetic Soul @ Nov 29 2006, 08:2...   Nov 30 2006, 20:26
||- - Martin H   QUOTE (tycho @ Nov 28 2006, 16:47) [...] ...   Nov 29 2006, 15:13
|- - awnm   Thanks for the new version - it's great. The n...   Dec 10 2006, 12:29
- - Synthetic Soul   It should work, unless your variable AlbumArtist c...   Nov 30 2006, 21:12
|- - wolfsong   QUOTE (Synthetic Soul @ Nov 30 2006, 14:1...   Dec 1 2006, 00:58
|- - Synthetic Soul   QUOTE (wolfsong @ Nov 30 2006, 23:58) I...   Dec 1 2006, 10:09
|- - wolfsong   QUOTE (Synthetic Soul @ Dec 1 2006, 03:09...   Dec 1 2006, 17:12
|- - Synthetic Soul   QUOTE (wolfsong @ Dec 1 2006, 16:12) I ju...   Dec 1 2006, 19:17
|- - wolfsong   QUOTE (Synthetic Soul @ Dec 1 2006, 12:17...   Dec 1 2006, 19:41
- - Synthetic Soul   I'm sorry, I should have been more clear: you ...   Dec 1 2006, 20:15
|- - wolfsong   QUOTE (Synthetic Soul @ Dec 1 2006, 13:15...   Dec 1 2006, 20:53
- - Dondo   Thanks Tycho for creating REACT. I'm finding i...   Dec 1 2006, 21:02
- - Synthetic Soul   QUOTE (wolfsong @ Dec 1 2006, 19:53) YEAH...   Dec 2 2006, 10:34
|- - Dondo   QUOTE (Synthetic Soul @ Dec 2 2006, 05:34...   Dec 2 2006, 22:53
- - SpiceWeasel   I've installed REACT 2 several times on Window...   Dec 3 2006, 00:28
|- - wolfsong   QUOTE (SpiceWeasel @ Dec 2 2006, 17:28) I...   Dec 3 2006, 00:48
|- - SpiceWeasel   QUOTE (wolfsong @ Dec 2 2006, 19:48) Are ...   Dec 3 2006, 20:14
- - FauDrei   Hi, Perhaps this information will spare someone...   Dec 4 2006, 00:44
|- - Mangix   QUOTE (FauDrei @ Dec 3 2006, 15:44) You c...   Dec 4 2006, 03:59
- - Synthetic Soul   It's down to how Windows creates directories. ...   Dec 4 2006, 11:35
- - tycho   Thanks for making me aware of this. Release 2.0 wi...   Dec 5 2006, 09:27
- - Synthetic Soul   Slightly OT, but, I had to upgrade to 3.2.1.10 (be...   Dec 5 2006, 10:20
|- - bhoar   QUOTE (Synthetic Soul @ Dec 5 2006, 04:20...   Dec 5 2006, 19:05
- - schnittlich   Just started using REACT 2 (been using the older v...   Dec 6 2006, 01:30
- - tycho   schnittlich: I can't see why this version shou...   Dec 11 2006, 13:35
|- - phaedra   QUOTE (tycho @ Dec 11 2006, 04:35) ... I ...   Dec 12 2006, 00:31
- - Meddler   First of all let me say thank you tycho. I've...   Dec 12 2006, 04:28
- - tycho   Meddler: You're welcome. 1) metamp3/mp3gain a...   Dec 12 2006, 10:28
|- - Meddler   QUOTE (tycho @ Dec 12 2006, 09:28) 1) met...   Dec 12 2006, 23:15
- - Synthetic Soul   Ooh. I did it already. I was reading the new wi...   Dec 12 2006, 11:46
- - drbeachboy   Hi tycho, Would you please explain to me why thes...   Dec 12 2006, 16:04
- - Synthetic Soul   If I understand correctly @AddCuesheetAG@ represen...   Dec 12 2006, 16:09
- - tycho   Yep, because of limitations in DOS scripting langu...   Dec 12 2006, 16:37
- - drbeachboy   tycho & SS, Thank you for the explanations.   Dec 12 2006, 18:04
- - robwade   tycho, Hello from a longtime enthusiast and first...   Dec 13 2006, 02:34
- - Ahmet   Hi everyone, First of all I have to express my ap...   Dec 13 2006, 10:14
- - tycho   @Meddler: You are correct. ApplyAlbumGain should p...   Dec 13 2006, 10:19
- - Ahmet   Thanks Tycho for your prompt answer!! I k...   Dec 13 2006, 10:55
- - tycho   I've just found a small glitch in the REACT-im...   Dec 13 2006, 13:05
- - Martin H   I would just like to say many thanks to the great ...   Dec 14 2006, 12:39
19 Pages V   1 2 3 > » 


Reply to this topicStart new topic
1 User(s) are reading this topic (1 Guests and 0 Anonymous Users)
0 Members:

 



RSS Lo-Fi Version Time is now: 28th July 2014 - 19:13