IPB

Welcome Guest ( Log In | Register )

> foobar2000 General Forum Rules

This is NOT a tech support forum.
Tech support questions go to foobar2000 Tech Support forum instead.

See also: Hydrogenaudio Terms of Service.

"hotness", An experiment in "meta-rating"
topdownjimmy
post Feb 6 2005, 18:15
Post #1





Group: Members
Posts: 525
Joined: 1-January 05
From: Boston
Member No.: 18762



Hotness is an algorithm that generates a score on a scale of 100 for every song in your library. It weighs frequency of play, rating, and recentness of last play against each other to determine how "hot" a song is. Because of its complex nature, its use of an absolute scale, and its awareness of time, it offers a unique alternative to other approaches to meta-rating (such as playcount rating).

Update: 18Aug2007 1.7.c

Lines 14-18 allow for easy alteration of which playback statistics tags to use. Default baselines have been greatly increased too, just because I find they work best for me. As always, experiment with them.
  • Paste into Columns UI's "Globals" tab in the Playlist view options
  • Requires foo_cwb_hooks to calculate date differences, and to automatically add %added% tag to newly imported tracks (under Tools/New File Tagger in Preferences)
  • Retrieve with $get_global(hotness)
Should work right out of the box for most setups, please let me know in this thread if there's anything I've overlooked or screwed up.

CODE
///////////////////////////////////////////
// HOTNESS - an algorithm for meta-rating
// v1.7.c (foo_cwb_hooks version)
// July 8, 2007 - by topdownjimmy@gmail.com
///////////////////////////////////////////
//
// configure baselines: define baseline playfrequency and decay period (in days)
//
$puts(baselinefrequency,90) // decrease if songs stay hot too long, or: high to accentuate success, low to accentuate recentness
$puts(baselinedecay,28) // decrease if too many songs are hot, or: high to accentuate success, low to accentuate recentness
//
// configure playback statistics
//
$puts(lp,[%last_played%])
$puts(fp,[%first_played%])
$puts(pc,[%play_count%])
$puts(rating,[%rating%])
$puts(avgrating,3)
//
// DO NOT EDIT BELOW THIS LINE //
$puts(baselinefrequency,$mul($get(baselinefrequency),24))
$puts(baselinedecay,$mul($get(baselinedecay),24))
$puts(lp_age,$add($substr($get(lp),12,13),$mul(24,$cwb_datediff($get(lp),2000-01-01))))
$puts(fp_age,$add($substr($get(fp),12,13),$mul(24,$cwb_datediff($get(fp),2000-01-01))))
$puts(age,$sub($get(lp_age),$get(fp_age)))
$puts(now_age,$add($substr(%cwb_systemdatetime%,12,13),$mul(24,$cwb_datediff(%cwb_systemdate%,2000-01-01))))
$puts(recentness,$sub($get(now_age),$get(lp_age)))
$puts(decay,$div($div($mul($get(pc),$get(baselinefrequency),$get(baselinedecay),$if2($get(rating),$get(avgrating)),100),$mul($max($get(age),$get(baselinefrequency)),$get(avgrating))),100))
$puts(rawhotness,$div($mul($max($sub($get(decay),$get(recentness)),0),100),$get(decay)))
$puts(forecast,$div($mul($max($sub($get(decay),$add($div($max(0,$sub($get(baselinedecay),$get(recentness))),2),$get(recentness))),0),100),$get(decay)))
$puts(hotness,$div($add($get(rawhotness),$get(forecast)),2))
$set_global(hotness,$get(hotness))
// END HOTNESS //



And here's a single-line version to be used in foo_playlist_tree. Put it into the "Population Order" field in a query, and limit to 20 (or whatever) subfolders.

CODE
$puts(baselinefrequency,45)$puts(baselinedecay,28)$puts(lp,[%last_played%])$puts(fp,[%first_played%])$puts(pc,[%play_count%])$puts(rating,[%rating%])$puts(avgrating,3)$puts(baselinefrequency,$mul($get(baselinefrequency),24))$puts(baselinedecay,$mul($get(baselinedecay),24))$puts(lp_age,$add($substr($get(lp),12,13),$mul(24,$cwb_datediff($get(lp),2000-01-01))))$puts(fp_age,$add($substr($get(fp),12,13),$mul(24,$cwb_datediff($get(fp),2000-01-01))))$puts(age,$sub($get(lp_age),$get(fp_age)))$puts(now_age,$add($substr(%cwb_systemdatetime%,12,13),$mul(24,$cwb_datediff(%cwb_systemdate%,2000-01-01))))$puts(recentness,$sub($get(now_age),$get(lp_age)))$puts(decay,$div($div($mul($get(pc),$get(baselinefrequency),$get(baselinedecay),$if2($get(rating),$get(avgrating)),100),$mul($max($get(age),$get(baselinefrequency)),$get(avgrating))),100))$puts(rawhotness,$div($mul($max($sub($get(decay),$get(recentness)),0),1000),$get(decay)))$puts(forecast,$div($mul($max($sub($get(decay),$add($div($max(0,$sub($get(baselinedecay),$get(recentness))),2),$get(recentness))),0),1000),$get(decay)))$num($div($add($get(rawhotness),$get(forecast)),2),4)




Log

1.7.c, 8Jul2007
-easy alteration of which playback statistics tags to use
-other minor cleanup

1.6.c.1, 6Dec2006
-improved softening technique to avoid spikes in hotness

Update 11Mar05
-added hourly decay version
-oops, updated again for hourly decay bugfix

Update 09Mar05
-added alternate %play_date% version

Update 22Feb05
-fixed avgrating bug

Update 18Feb05
-"begin decay immediately" is now optional
-uses new LAST_PLAYED standard
-if an %added% tag is absent, it assumes the baseline frequency for the song
-configurable "default rating" (assumes default rating when there is none)
-plan to employ FIRST_PLAYED standard once it's implemented

Code updated 10Feb05
-decay now begins immediately rather than the day after last play


History/Approach (some info outdated)

Before using this code, remember that three tags are NECESSARY for it to work: %first_played%, %last_played%, and %play_counter%, provided by foo_playcount 1.9.2

%rating% will also affect things, but isn't essential.


So I had this idea that there are a number of statistics contained within each one of my tracks that are related to the overall "hotness" (or "popularity" or what have you) of a song: %play_counter%, %rating%, %last_played%, and %first_played%. But no algorithm had been designed yet that would weigh all of those factors in the calculation of one single score that measures what I'm calling "hotness."

Rating is all fine and dandy, but it's so cut and dry. Same goes for last_played and play_counter. They're such dead, linear statistics that aren't very interesting to me to watch at all. And play_counter is rendered meaningless unless it's compared to how long a song's been in your library. Complexity was the goal of this idea, the dynamic generation of a song's overall...SOMETHINGness that I couldn't easily predict. It does no good to tell me that I rated a song 5 stars. I know I did, I was there. And keep in mind, this isn't about determining a song's quality or "goodness"; goodness is given by rating. Hotness is something much more interesting, and I hope I'm on my way to a satisfactory representation of it.

To begin, I believe the importance of these factors in decreasing order is:
-recentness of last play
-overall frequency of play (play_counter days since added ("age"))
-rating

When a song is played, its hotness should be given a boost (the amount of this boost is detailed below). As time passes since the last time a song was played, that song's hotness should decrease. So now we've got to define a decay period: the time it takes before a song's hotness dwindles to 0 again. The two factors that determine the length of this decay period are rating and play frequency.

The definition of this decay period depends on two lengths of time: baseline FREQUENCY and baseline DECAY. In the code below, baselinefrequency is set at 14 days and baselinedecay at 6 days. But, depending on your listening habits, you may need to alter these settings. The effect the settings have isn't immediately intuitive, but a good rule of thumb is:

-the more often you listen to music, the LOWER baselinedecay should be
-the more variety of music you listen to, the HIGHER baselinefrequency should be

Setting baselinefrequency to 14 and baselinedecay to 6 means that a song played on average once every 14 days will decay to 0% hotness 6 days after it's played. If a song is played TWICE every 14 days, its decay period will DOUBLE (12 days). If a song is played once every 28 days, its decay period will halve (3 days).

Likewise, rating will affect a song's decay period. The absence of a rating will assume a default rating of 3. A rating of 5 will multiply the decay period by 5/3, and a rating of 1 will multiply the decay period by 1/5.

The initial boost of playing a song used to be 100% hotness. This made for boring playlists when looking at songs that were played "today," so in the current code, the immediate hotness is what the hotness would be TOMORROW if the hotness were to go up to 100% today. This makes for some interesting effects; for instance, my settings make it so that a song added today and played once today begins at a hotness of 83%. If I play it again today, I then double its play frequency, thus doubling its decay period, thus boosting its hotness.

Here's the code:

CODE
/////////////////////////////////////////
// HOTNESS - an algorithm for meta-rating
// %last_played% version
/////////////////////////////////////////

// baselines: define baseline frequency and decay periods
//
// baselinefrequency: decrease if songs stay hot too long
// baselinedecay: decrease if too many songs are hot
//
$puts(baselinefrequency,14)
$puts(baselinedecay,7)

// begin decay immediately? (1=yes, 0=no)
$puts(begindecaynow,1)

// default rating for unrated songs
$puts(avgrating,3)

// calculate "age": the number of days the song has been in the library
$if(%added%,
$puts(age,
$sub(
$add(
$mul($right(%_system_year%,2),365),
$select(%_system_month%,0,31,59,90,120,151,181,212,243,273,304,334),
$ifequal($mod(%_system_year%,4),0,$ifgreater(%_system_month%,2,1,0),0),
%_system_day%
),
$add(
$mul($substr(%added%,3,4),365),
$select($substr(%added%,5,6),0,31,59,90,120,151,181,212,243,273,304,334),
$ifequal($mod($substr(%added%,1,4),4),0,$ifgreater($substr(%added%,5,6),2,1,0),0),
$right(%added%,2)
)
)
),
$puts(age,$mul(%play_counter%,$get(baselinefrequency)))
)

// calculate "recentness": number of days since song was last played
$puts(recentness,
$sub(
$add(
$mul($right(%_system_year%,2),365),
$select(%_system_month%,0,31,59,90,120,151,181,212,243,273,304,334),
$ifequal($mod(%_system_year%,4),0,$ifgreater(%_system_month%,2,1,0),0),
%_system_day%
),
$add(
$mul($substr(%last_played%,3,4),365),
$select($substr(%last_played%,6,7),0,31,59,90,120,151,181,212,243,273,304,334),
$ifequal($mod($substr(%last_played%,1,4),4),0,$ifgreater($substr(%last_played%,6,7),2,1,0),0),
$substr(%last_played%,9,10)
)
)
)

// calculate "decay": the specific decay period
$puts(decay,$div($mul(%play_counter%,$get(baselinefrequency),$get(baselinedecay)
,$if2(%rating%,$get(avgrating))),$mul($max($get(age),$get(baselinefrequency)),$get(avgrating))))

// calculate "hotness"
hotness=$div($mul($max($sub($get(decay),$add(
$get(recentness),$get(begindecaynow))),0),100),$get(decay))

//////////////////////////////


For compatibility with foo_playcount's default play_date settings:

CODE
/////////////////////////////////////////
// HOTNESS - an algorithm for meta-rating
// %play_date% version
/////////////////////////////////////////

// baselines: define baseline frequency and decay periods
//
// baselinefrequency: decrease if songs stay hot too long
// baselinedecay: decrease if too many songs are hot
//
$puts(baselinefrequency,14)
$puts(baselinedecay,7)

// begin decay immediately? (1=yes, 0=no)
$puts(begindecaynow,1)

// default rating for unrated songs
$puts(avgrating,3)

// calculate "age": the number of days the song has been in the library
$if(%added%,
$puts(age,
$sub(
$add(
$mul($right(%_system_year%,2),365),
$select(%_system_month%,0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($right(%_system_year%,2),4),$if($or($greater(%_system_month%,2),$greater($mod(%_system_year%,4),0)),1,0)),
%_system_day%
),
$add(
$mul($substr(%added%,3,4),365),
$select($substr(%added%,5,6),0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($substr(%added%,3,4),4),$if($or($greater($substr(%added%,5,6),2),$greater($mod($substr(%added%,1,4),4),0)),1,0)),
$right(%added%,2)
)
)
),
$puts(age,$mul(%play_counter%,$get(baselinefrequency)))
)

// calculate "recentness": number of days since song was last played
$puts(recentness,
$sub(
$add(
$mul($right(%_system_year%,2),365),
$select(%_system_month%,0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($right(%_system_year%,2),4),$if($or($greater(%_system_month%,2),$greater($mod(%_system_year%,4),0)),1,0)),
%_system_day%
),
$add(
$mul($substr(%play_date%,5,6),365),
$select($substr(%play_date%,3,4),0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($substr(%play_date%,5,6),4),$if($or($greater($substr(%play_date%,3,4),2),$greater($mod($substr(%play_date%,5,6),4),0)),1,0)),
$substr(%play_date%,1,2)
)
)
)

// calculate "decay": the specific decay period
$puts(decay,$div($mul(%play_counter%,$get(baselinefrequency),$get(baselinedecay),$if2(%rating%,$get(avgrating))),$mul($max($get(age),$get(baselinefrequency)),3)))

// calculate "hotness"
hotness=$div($mul($max($sub($get(decay),$add($get(recentness),$get(begindecaynow))),0),100),$get(decay))

//////////////////////////////


And an hourly decay version...this version does not include the "begin decay immediately" option because decay will begin in an hour anyway.

CODE
/////////////////////////////////////////
// HOTNESS - an algorithm for meta-rating
// hourly decay version
/////////////////////////////////////////

// baselines: define baseline frequency and decay periods
//
// baselinefrequency: decrease if songs stay hot too long
// baselinedecay: decrease if too many songs are hot
//
$puts(baselinefrequency,14)
$puts(baselinedecay,7)

// default rating for unrated songs
$puts(avgrating,3)

// convert baselines to hours
$puts(baselinefrequency,$mul($get(baselinefrequency),24))
$puts(baselinedecay,$mul($get(baselinedecay),24))

// calculate "age": the number of hours the song has been in the library
$if(%added%,
$puts(age,
$sub(
$add(
$mul(
$add(
$mul($right(%_system_year%,2),365),
$select(%_system_month%,0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($right(%_system_year%,2),4),$if($or($greater(%_system_month%,2),$greater($mod(%_system_year%,4),0)),1,0)),
%_system_day%
),
24
),
%_system_hour%
)
,
$mul(
$add(
$mul($substr(%added%,3,4),365),
$select($substr(%added%,5,6),0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($substr(%added%,3,4),4),$if($or($greater($substr(%added%,5,6),2),$greater($mod($substr(%added%,1,4),4),0)),1,0)),
$right(%added%,2)
),
24
)
)
)
,
$puts(age,$mul(%play_counter%,$get(baselinefrequency)))
)

// calculate "recentness": number of hours since song was last played
$puts(recentness,
$sub(
$add(
$mul(
$add(
$mul($right(%_system_year%,2),365),
$select(%_system_month%,0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($right(%_system_year%,2),4),$if($or($greater(%_system_month%,2),$greater($mod(%_system_year%,4),0)),1,0)),
%_system_day%
),
24
),
%_system_hour%
)
,
$add(
$mul(
$add(
$mul($substr(%last_played%,3,4),365),
$select($substr(%last_played%,6,7),0,31,59,90,120,151,181,212,243,273,304,334),
$add($div($substr(%last_played%,3,4),4),$if($or($greater($substr(%last_played%,6,7),2),$greater($mod($substr(%last_played%,1,4),4),0)),1,0)),
$substr(%last_played%,9,10)
),
24
),
$substr(%last_played%,12,13)
)
)
)

// calculate "decay": the specific decay period
$puts(decay,$div($mul(%play_counter%,$get(baselinefrequency),$get(baselinedecay),$if2(%rating%,$get(avgrating))),$mul($max($get(age),$get(baselinefrequency)),3)))

// calculate "hotness"
hotness=$div($mul($max($sub($get(decay),$get(recentness)),0),100),$get(decay))

//////////////////////////////


Paste into the "Variables" tab under the "Globals" tab in Columns UI settings, and make sure that "Make date info available" and "Use global variables for display" are both checked. Now you are free to use %_hotness% anywhere in your columns! It will appear on a scale of 100. Because this statistic is so effluvial, I think it will be best depicted in color, perhaps as a shade of red on a dot. To do this, create a column with ● as the display, check "Use custom colour spec," and in the "Colour" tab, type:

CODE
$blend(FFFFFF,0000FF,%_hotness%,100)|
$blend(FFFFFF,0000FF,%_hotness%,100)|
FFFFFF|
FFFFFF


You will, of course, have to change some of those colors to match your other colors.

Here's how things look for me:



On the far right is the "hotness" indicator, which fades from bright orange to the navy background color as hotness decreases. The six columns of numbers on the right are (from left to right):

playcount, rating, overall age, recentness of last play, decay period remaining, hotness percentage

The songs selected are the most interesting natural occurrences of hotness in my library so far. There's a lot going on, but I encourage you to study the hotness number on the right, and then determine how the song's statistics produced that hotness. Why are some Beck songs totally expired while others are very hot?, for example.

And, just for fun, an image of an ideal world where hotness replaces any display of rating or playcount at all:



Or you can sort by hotness:



You'll have to excuse me for the lengthiness of this post, but I like this idea a lot, and I welcome any and all feedback, so please let me know if you have any advice.

Thanks for your attention. rolleyes.gif


This post has been edited by topdownjimmy: Feb 16 2008, 17:55
Go to the top of the page
+Quote Post
 
Start new topic
Replies
Lyx
post Feb 19 2005, 20:54
Post #2





Group: Members
Posts: 3353
Joined: 6-July 03
From: Sachsen (DE)
Member No.: 7609



okay, thanks for explaining this. So i can just scrap this line if i dont need it THAT accurate to save resources.


--------------------
I am arrogant and I can afford it because I deliver.
Go to the top of the page
+Quote Post

Posts in this topic
- topdownjimmy   "hotness"   Feb 6 2005, 18:15
- - upNorth   I read through rather quickly, but the topic is in...   Feb 6 2005, 19:23
|- - topdownjimmy   QUOTE (upNorth @ Feb 6 2005, 01:23 PM)To me i...   Feb 6 2005, 19:43
|- - jkwarras   QUOTE (topdownjimmy @ Feb 6 2005, 10:43 AM)In...   Feb 8 2005, 00:17
- - upNorth   Yes, of course my simple solution doesn't come...   Feb 6 2005, 20:18
|- - topdownjimmy   QUOTE (upNorth @ Feb 6 2005, 02:18 PM)As you ...   Feb 6 2005, 20:27
|- - upNorth   QUOTE (topdownjimmy @ Feb 6 2005, 08:27 PM)%a...   Feb 6 2005, 20:37
- - Zurman   Very interesting idea indeed. topdownjimmy, did y...   Feb 6 2005, 21:00
|- - topdownjimmy   QUOTE (Zurman @ Feb 6 2005, 03:00 PM)Very int...   Feb 6 2005, 21:13
- - topdownjimmy   edit: deleted entire post, because it became irrel...   Feb 7 2005, 03:11
- - jkwarras   Very interesting. I'll surely give a try to it...   Feb 7 2005, 11:49
- - topdownjimmy   I hope no one minds that I'm "bumping...   Feb 11 2005, 01:18
- - Smitty Jones   topdownjimmy and i have been communicating recentl...   Feb 11 2005, 18:06
- - jkwarras   [quote=topdownjimmy,Feb 6 2005, 09:15 AM] Before u...   Feb 16 2005, 19:49
- - Lyx   @topdown How did you add the %added%-tag? manuall...   Feb 17 2005, 23:31
|- - upNorth   QUOTE (Lyx @ Feb 17 2005, 11:31 PM)@topdown ...   Feb 17 2005, 23:34
|- - jkwarras   QUOTE (Lyx @ Feb 17 2005, 02:31 PM)How did yo...   Feb 18 2005, 16:15
- - Lyx   Thanks, shame on me :-)   Feb 17 2005, 23:43
- - falconfox   this looks like a cool idea. i can't seem to g...   Feb 18 2005, 02:36
- - Smitty Jones   @falconfox do you have the "make date info av...   Feb 18 2005, 08:20
- - falconfox   yeah i have both of those checked. it is wierd. i ...   Feb 18 2005, 09:53
|- - upNorth   QUOTE (falconfox @ Feb 18 2005, 09:53 AM)Ther...   Feb 18 2005, 10:31
- - topdownjimmy   Wow, surprised at the sudden burst of interest thi...   Feb 18 2005, 13:04
- - stroke   how can i make the hotness dots display in differe...   Feb 18 2005, 14:16
- - addicted   hey topdownjimmy, i've been watching this thre...   Feb 18 2005, 14:29
- - hit_ny   QUOTE Rating is all fine and dandy, Taken on thie...   Feb 18 2005, 19:51
|- - Lyx   QUOTE (hit_ny @ Feb 18 2005, 08:51 PM)Taken o...   Feb 18 2005, 20:37
|- - topdownjimmy   QUOTE (hit_ny @ Feb 18 2005, 01:51 PM)QUOTE W...   Feb 19 2005, 00:02
- - falconfox   i am still not getting any colors for my dots, i h...   Feb 18 2005, 23:10
|- - topdownjimmy   QUOTE (falconfox @ Feb 18 2005, 05:10 PM)i am...   Feb 18 2005, 23:54
- - Lyx   Maybe i will implement this idea later if PLAY_FIR...   Feb 19 2005, 00:14
|- - topdownjimmy   QUOTE (Lyx @ Feb 18 2005, 06:14 PM)After i di...   Feb 19 2005, 00:31
||- - Lyx   QUOTE (topdownjimmy @ Feb 19 2005, 01:31 AM)I...   Feb 19 2005, 00:55
||- - topdownjimmy   QUOTE (Lyx @ Feb 18 2005, 06:55 PM)because al...   Feb 19 2005, 01:02
||- - topdownjimmy   QUOTE (Lyx @ Feb 18 2005, 06:55 PM)edit: what...   Feb 19 2005, 01:05
||- - Lyx   QUOTE (topdownjimmy @ Feb 19 2005, 02:05 AM)I...   Feb 19 2005, 01:16
|- - topdownjimmy   QUOTE (Lyx @ Feb 18 2005, 06:14 PM)Else, when...   Feb 19 2005, 00:54
- - falconfox   still nothing, even with the new formatting. i am ...   Feb 19 2005, 00:22
|- - topdownjimmy   QUOTE (falconfox @ Feb 18 2005, 06:22 PM)stil...   Feb 19 2005, 00:34
- - falconfox   i get ? when i just put in _hotness I'm not gi...   Feb 19 2005, 00:39
|- - topdownjimmy   QUOTE (falconfox @ Feb 18 2005, 06:39 PM)i ge...   Feb 19 2005, 00:45
- - upNorth   @falconfox: Make sure there is a square at the end...   Feb 19 2005, 00:43
- - falconfox   yeah it is all there, i mean i copied the entire c...   Feb 19 2005, 00:45
- - falconfox   yeah i just repasted it and i am getting ? still. ...   Feb 19 2005, 00:48
- - Lyx   falcon: which browser do you use? You may have a c...   Feb 19 2005, 00:57
|- - falconfox   QUOTE (Lyx @ Feb 18 2005, 05:57 PM)falcon: wh...   Feb 19 2005, 00:58
|- - Lyx   QUOTE (falconfox @ Feb 19 2005, 01:58 AM)fire...   Feb 19 2005, 01:01
- - falconfox   I don't know, i think i am doing everything co...   Feb 19 2005, 01:08
- - Lyx   Okay, now i get it - your idea is to rate the ...   Feb 19 2005, 01:13
- - falconfox   it is wierd, when i have that code in my column di...   Feb 19 2005, 01:47
- - Smitty Jones   hey, will you make it optional to use YYYYMMDD or ...   Feb 19 2005, 06:27
|- - topdownjimmy   QUOTE (Smitty Jones @ Feb 19 2005, 12:27 AM)h...   Feb 19 2005, 16:56
- - Lyx   @topdownjimmy In your code when calculating the ...   Feb 19 2005, 19:43
|- - topdownjimmy   QUOTE (Lyx @ Feb 19 2005, 01:43 PM)@topdownji...   Feb 19 2005, 20:36
- - Lyx   okay, thanks for explaining this. So i can just sc...   Feb 19 2005, 20:54
|- - topdownjimmy   QUOTE (Lyx @ Feb 19 2005, 02:54 PM)okay, than...   Feb 19 2005, 20:56
|- - Lyx   QUOTE (topdownjimmy @ Feb 19 2005, 09:56 PM)A...   Feb 19 2005, 22:20
- - hit_ny   I would like to pose a fundamental question. Wha...   Feb 19 2005, 21:25
- - addicted   so you mean you rate all your albums and then sort...   Feb 19 2005, 21:31
|- - hit_ny   QUOTE (addicted @ Feb 19 2005, 08:31 PM)so yo...   Feb 19 2005, 23:07
- - upNorth   It's intended to show you if a track is hot or...   Feb 19 2005, 23:21
|- - hit_ny   QUOTE (upNorth @ Feb 19 2005, 10:21 PM)It...   Feb 20 2005, 09:32
|- - topdownjimmy   QUOTE (upNorth @ Feb 19 2005, 05:21 PM)It...   Feb 20 2005, 15:20
- - falconfox   @ topdownjimmy: hey can you post your columns conf...   Feb 20 2005, 00:00
|- - topdownjimmy   QUOTE (falconfox @ Feb 19 2005, 06:00 PM)@ to...   Feb 20 2005, 16:21
|- - falconfox   QUOTE (topdownjimmy @ Feb 20 2005, 09:21 AM)Q...   Feb 21 2005, 01:15
- - Lyx   I've thought about this whole hotness-idea a b...   Feb 20 2005, 07:35
- - falconfox   I got it to work finally. i found out that i neede...   Feb 21 2005, 02:20
- - lav-chan   Maybe i'm totally confused about how this work...   Feb 21 2005, 17:16
|- - jkwarras   QUOTE (Lav @ Feb 21 2005, 08:16 AM)I have LAS...   Feb 21 2005, 18:37
- - lav-chan   If that's the case, that's stupid (why two...   Feb 21 2005, 20:22
|- - Lyx   QUOTE (Lav @ Feb 21 2005, 09:22 PM)If that...   Feb 21 2005, 20:51
- - lav-chan   Yes, but he said that he added... the... ADDED... ...   Feb 21 2005, 21:00
|- - topdownjimmy   QUOTE (Lav @ Feb 21 2005, 03:00 PM)Yes, but h...   Feb 22 2005, 03:49
- - lav-chan   I have a column with nothing in it but %_hotness%....   Feb 22 2005, 06:44
|- - C00I90WN   QUOTE (Lav @ Feb 22 2005, 02:44 AM)I have a c...   Feb 22 2005, 09:58
- - lav-chan   Oh wow. I NEVER would have figured that out. Thank...   Feb 22 2005, 10:14
|- - C00I90WN   QUOTE (Lav @ Feb 22 2005, 06:14 AM)Oh wow. I ...   Feb 22 2005, 10:28
- - lav-chan   Rad, now that it more or less works, i have some q...   Feb 22 2005, 11:16
|- - topdownjimmy   QUOTE (Lav @ Feb 22 2005, 05:16 AM)Is there a...   Feb 22 2005, 15:51
- - JEN   This is fantastic! I can't believe I only...   Feb 22 2005, 15:40
|- - topdownjimmy   QUOTE (JEN @ Feb 22 2005, 09:40 AM)I had a si...   Feb 22 2005, 15:56
- - JEN   Oh! i thought it was a similar sort of thing ...   Feb 22 2005, 16:49
- - falconfox   decaying on an hourly basis would be pretty sweet....   Feb 22 2005, 20:38
- - eliazu   how do i make a database explorer tree of hotness?...   Feb 26 2005, 15:10
|- - topdownjimmy   QUOTE (eliazu @ Feb 26 2005, 09:10 AM)how do ...   Feb 26 2005, 16:15
|- - eliazu   QUOTE (topdownjimmy @ Feb 26 2005, 05:15 PM)Q...   Feb 26 2005, 17:26
|- - jkwarras   QUOTE (topdownjimmy @ Feb 26 2005, 07:15 AM)(...   Feb 26 2005, 17:38
- - krazy   QUOTE (C00I90WN @ Feb 22 2005, 04:58 PM)For a...   Feb 27 2005, 07:45
- - Smitty Jones   something strange has occured... as i was listeni...   Mar 1 2005, 21:20
|- - topdownjimmy   QUOTE (Smitty Jones @ Mar 1 2005, 03:20 PM)so...   Mar 2 2005, 00:30
- - Smitty Jones   ahh, alright. that works better... the last_play...   Mar 2 2005, 01:16
- - Animekiksazz   I've been using Play Count for a while now, bu...   Mar 2 2005, 08:56
|- - stripe   I get hotness=0 for all my songs, no matter what t...   Mar 2 2005, 10:41
|- - topdownjimmy   QUOTE (Animekiksazz @ Mar 2 2005, 02:56 AM)I...   Mar 10 2005, 00:39
|- - topdownjimmy   QUOTE (Animekiksazz @ Mar 2 2005, 02:56 AM)Al...   Mar 10 2005, 01:53
- - jkwarras   I'm trying (again) to make hotness work with p...   Mar 9 2005, 22:46
|- - topdownjimmy   QUOTE (jkwarras @ Mar 9 2005, 04:46 PM)I...   Mar 9 2005, 23:45
|- - jkwarras   QUOTE (topdownjimmy @ Mar 9 2005, 02:45 PM)Wo...   Mar 10 2005, 11:55
- - Animekiksazz   Thanks, I tried it out, however I just get "?...   Mar 10 2005, 07:23
4 Pages V   1 2 3 > » 


Reply to this topicStart new topic
1 User(s) are reading this topic (1 Guests and 0 Anonymous Users)
0 Members:

 



RSS Lo-Fi Version Time is now: 23rd July 2014 - 22:48